home *** CD-ROM | disk | FTP | other *** search
/ Amiga Plus 1995 #5 & #6 / Amiga Plus CD - 1995 - No. 5 and 6.iso / tex / mf / inputs / dc / dxrdigit.mf < prev    next >
Text File  |  1994-04-12  |  15KB  |  327 lines
  1. % This is DXRDIGIT.MF in text format, as of March 24, 1992
  2. %
  3. % DC fonts Version 1.1 (prerelease of EC fonts)
  4. %
  5. %          [ heavily borrowed from the Computer Modern Roman family of
  6. %            fonts by D. E. Knuth ]
  7. %
  8. % Content:
  9. %
  10. %  roman numerals 0 .. 9
  11. %
  12. % All digits have the same height, width, depth, and italic correction.
  13.  
  14. dcchar "The numeral 0";
  15. beginchar("0",9u#,fig_height#,0);
  16. italcorr fig_height#*slant-.5u#;
  17. adjust_fit(0,0);
  18. penpos1(vair,90); penpos3(vair,-90); penpos2(curve,180); penpos4(curve,0);
  19. if not monospace: interim superness:=sqrt(more_super*hein_super); fi
  20. x2r=hround max(.7u,1.45u-.5curve); x4r=w-x2r; x1=x3=.5w;
  21. y1r=h+o; y3r=-o; y2=y4=.5h-vair_corr; y2l:=y4l:=.52h;
  22. penstroke pulled_arc.e(1,2) & pulled_arc.e(2,3)
  23.  & pulled_arc.e(3,4) & pulled_arc.e(4,1) & cycle;  % bowl
  24. penlabels(1,2,3,4); endchar;
  25.  
  26. dcchar "The numeral 1";
  27. beginchar("1",9u#,fig_height#,0);
  28. italcorr fig_height#*slant-.5u#;
  29. adjust_fit(0,0);
  30. numeric light_stem; light_stem=hround .4[stem',cap_stem'];
  31. pickup tiny.nib;
  32. pos1(light_stem,0); pos2(light_stem,0);
  33. lft x1l=lft x2l=hround(.5(w+.5u)-.5cap_stem'); top y1=h+o; bot y2=0;
  34. filldraw stroke z1e--z2e;  % stem
  35. if not serifs: save slab; slab=bar; fi
  36. dish_serif(2,1,a,1/3,min(2.25u,lft x2l-1.5u),
  37.   b,1/3,min(2.25u,w-1.25u-rt x2r)); % serif
  38. pickup crisp.nib; pos3(slab,-90); pos4(bar,-90);
  39. top y3l=h+o; top y4l=if monospace: .8 else: .9 fi\\ h+o;
  40. lft x4=max(1.25u,tiny.lft x1l-2.35u);
  41. tiny.rt x1r=lft x3+.25[tiny,hair];
  42. erase fill z3l{x4l-x3l,3(y4l-y3l)}...z4l{left}
  43.  --(x4l,h+o+1)--(x3l,h+o+1)--cycle; % erase excess at top
  44. filldraw stroke z3e{x4e-x3e,3(y4e-y3e)}..z4e{left};  % point
  45. penlabels(1,2,3,4); endchar;
  46.  
  47. dcchar "The numeral 2";
  48. beginchar("2",9u#,fig_height#,0);
  49. italcorr fig_height#*slant-.5u#;
  50. adjust_fit(0,0);
  51. numeric arm_thickness, hair_vair; hair_vair=.25[vair,hair];
  52. arm_thickness=Vround(if hefty:slab+2stem_corr else:.4[stem,cap_stem] fi);
  53. pickup crisp.nib; pos7(arm_thickness,-90); pos8(hair,0);
  54. bot y7r=0; lft x7=hround .9u; rt x8r=hround(w-.9u); y8=good.y(y7l+beak/2)+eps;
  55. arm(7,8,a,.3beak_darkness,beak_jut);  % arm and beak
  56. pickup fine.nib; pos2(slab,90); pos3(.4[curve,cap_curve],0);
  57. top y2r=h+o; x2=.5(w-.5u); rt x3r=hround(w-.9u); y3+.5vair=.75h;
  58. if serifs: numeric bulb_diam; bulb_diam=hround(flare+2/3(cap_stem-stem));
  59.  pos0(bulb_diam,180); pos1(cap_hair,180);
  60.  lft x1r=hround .9u; y1-.5bulb_diam=2/3h;
  61.  (x,y2l)=whatever[z1l,z2r]; x2l:=x; bulb(2,1,0);  % bulb and arc
  62. else: x2l:=x2l-.25u; pos1(flare,angle(-9u,h));
  63.  lft x1r=hround .75u; bot y1l=vround .7h; y1r:=good.y y1r+eps; x1l:=good.x x1l;
  64.  filldraw stroke term.e(2,1,left,.9,4); fi  % terminal and arc
  65. pos4(.25[hair_vair,cap_stem],0);
  66. pos5(hair_vair,0); pos6(hair_vair,0);
  67. y5=arm_thickness; y4=.3[y5,y3]; top y6=min(y5,slab,top y7l);
  68. lft x6l=crisp.lft x7; z4l=whatever[z6l,(x3l,bot .58h)]; z5l=whatever[z6l,z4l];
  69. erase fill z4l--z6l--lft z6l--(lft x6l,y4l)--cycle;  % erase excess at left
  70. filldraw stroke z2e{right}..tension atleast .9 and atleast 1
  71.  ..z3e{down}.. z4e---z5e--z6e;  % stroke
  72. penlabels(0,1,2,3,4,5,6,7,8); endchar;
  73.  
  74. dcchar "The numeral 3";
  75. beginchar("3",9u#,fig_height#,0);
  76. italcorr fig_height#*slant-.5u#;
  77. adjust_fit(0,0);
  78. numeric top_thickness,mid_thickness,bot_thickness;
  79. top_thickness=max(fine.breadth,vround(slab-2vair_corr));
  80. mid_thickness=max(fine.breadth,vround 2/3vair);
  81. bot_thickness=max(fine.breadth,vround(slab-vair_corr));
  82. pickup fine.nib; pos2(top_thickness,90); top y2r=h+o;
  83. pos3(max(fine.breadth,.6[curve,cap_curve]-stem_corr),0);
  84. rt x3r=hround(w-1.25u);
  85. pos4(vair,-90); pos5(vair,-90);
  86. pos6(mid_thickness,90); x2=x6=x8=.5[1.5u,x7];
  87. pos7(cap_curve,0); rt x7r=hround(w-.75u); lft x5=min(hround 3u,lft x6)-eps;
  88. pos8(bot_thickness,-90); bot y8r=-o;
  89. y3=.6[top y4l,bot y2l]; y7=.5[bot y6l,top y8l];
  90. top y5l=vround(.54h+.5vair); y5r=y6l;
  91. x4=1/3[x5,x3l]; z4=z5+whatever*(150u,h);
  92. filldraw stroke pulled_super_arc.e(2,3)(.5superpull)
  93.  & z3e{down}...z4e---z5e;  % upper bowl
  94. filldraw z5r--z6l--z6r--z5l---cycle;  % middle tip
  95. filldraw stroke pulled_super_arc.e(6,7)(.5superpull)
  96.  & pulled_super_arc.e(7,8)(.5superpull);  % lower bowl
  97. if serifs: numeric bulb_diam[];
  98.  bulb_diam1=flare+.5(cap_stem-stem); bulb_diam2=flare+cap_stem-stem;
  99.  pos0(bulb_diam1,180); pos1(hair,180);
  100.  lft x0r=hround 1.25u; y0=min(.9h-.5bulb_diam1,.75h+.5bulb_diam1);
  101.  bulb(2,1,0);  % upper bulb
  102.  pos10(bulb_diam2,-180); pos9(cap_hair,-180);
  103.  lft x10r=hround .75u; y10=max(.1h+.5bulb_diam2,.3h-.5bulb_diam2);
  104.  bulb(8,9,10);  % lower bulb
  105. else: pos1(.5[vair,flare],angle(-8u,h));
  106.  lft x1r=hround u; bot y1l=vround .75h+o;
  107.  y1r:=good.y y1r+eps; x1l:=good.x x1l;
  108.  pos9(bot_thickness,angle(-2u,-h));
  109.  lft x9r=hround .75u; top y9l=vround .25h-o;
  110.  y9r:=good.y y9r-eps; x9l:=good.x x9l;
  111.  filldraw stroke term.e(2,1,left,1,4);  % upper terminal
  112.  filldraw stroke term.e(8,9,left,1,4); fi  % lower terminal
  113. penlabels(0,1,2,3,4,5,6,7,8,9,10); endchar;
  114.  
  115. dcchar "The numeral 4";
  116. beginchar("4",9u#,fig_height#,0);
  117. italcorr fig_height#*slant-.5u#;
  118. adjust_fit(0,0);
  119. numeric light_stem, light_stem', diag_stem, alpha, cut; cut=.75notch_cut;
  120. light_stem=hround .4[fudged.stem,fudged.cap_stem];
  121. light_stem'=hround max(tiny.breadth,light_stem-2stem_corr);
  122. diag_stem=max(tiny.breadth,.4[vair,fudged.hair]);
  123. pickup crisp.nib; pos5(cap_bar,90); pos6(cap_bar,90);
  124. lft x5=hround .5u; rt x6=hround(w-.5u);
  125. top y5r=vround(if serifs: 5/18[slab,h-light_stem]+1
  126.  else:.35(h-light_stem) fi+.5cap_bar);
  127. z4l=top lft z5r; y2=y2'=y5=y6; x1r=x2r=hround(w-3u+.5light_stem);
  128. penpos1(light_stem',0); penpos2(light_stem',0); y1=y3=h+apex_o+apex_oo;
  129. x3r+apex_corr=x1r; alpha=diag_ratio(1,diag_stem,y3-y4l,x3r-x4l);
  130. penpos3(alpha*diag_stem,0); penpos4(alpha*diag_stem,0);
  131. x0=x1l; z0=whatever[z3r,z4r];
  132. x5'=x5; z5''=z5'+penoffset z4-z3 of currentpen=whatever[z4l,z3l];
  133. fill diag_end(2r,1r,1,.5,3l,4l)---z5''...lft z5'
  134.  ---lft z5l -- (x4r,y5l) -- z4r
  135.  if y0<h-cut:{z3r-z4r}...{up}(x1l-1,h-cut)
  136.   --(x1l,h-cut) else: -- z0 fi
  137.  --z2l--z2r--cycle;  % diagonal and upper stem
  138. filldraw stroke z5e--z6e;  % bar
  139. pickup tiny.nib; pos7(light_stem,0); rt x7r=x1r; bot y7=0;
  140. pos2'(light_stem,0); x2'=x7;
  141. filldraw stroke z2'e--z7e;  % lower stem
  142. if serifs: dish_serif(7,2',a,1/3,1.75u,
  143.   b,1/3,min(1.75u,w-.5u-rt x7r)); fi  % serif
  144. penlabels(0,1,2,3,4,5,6,7); endchar;
  145.  
  146. dcchar "The numeral 5";
  147. beginchar("5",9u#,fig_height#,0);
  148. italcorr fig_height#*slant-.5u#;
  149. adjust_fit(0,0);
  150. numeric bot_thickness,light_hair;
  151. bot_thickness=max(fine.breadth,vround(slab-vair_corr));
  152. light_hair=hround(cap_hair if hefty: -\\2stem_corr fi);
  153. pickup tiny.nib; pos5(vair,180); pos6(vair,90);
  154. bot y5=vround(.53h-vair); top y6r=max(vround .61803h+o,top y6r+y5+eps-y6l);
  155. pos3(light_hair,0); pos4(light_hair,0);
  156. lft x3l=max(1.35u,2.1u-.5light_hair); x3=x4=x5; y4=y5;
  157. top y3=h if not hefty: +\\o fi;
  158. filldraw stroke z3e--z4e;  % thin stem
  159. penpos7(cap_stem-fine,0); penpos8(bot_thickness-fine,-90);
  160. fine.rt x7r=hround(w-.9u); x8=.5[u,x7]; x6=.5[x5,x7];
  161. erase fill z5--bot z5--(x6,bot y5)--z6{left}
  162.  ..tension .9 and 1..{x5-x6,3(y5-y6)}cycle; % erase excess in middle
  163. filldraw stroke z6e{left}..tension .9 and 1..{x5-x6,3(y5-y6)}z5e;  % link
  164. pickup fine.nib; pos6'(vair,90); z6'=z6;
  165. y7=.5[y6,y8]; bot y8r=-o;
  166. filldraw stroke pulled_arc.e(6',7) & pulled_arc.e(7,8);  % bowl
  167. if serifs: pos9(hair,-180); y9=.5y5; lft x9r=hround .9u;
  168.  pos10(flare+1/3(cap_stem-stem),-180); bulb(8,9,10);  % bulb
  169. else: pos9(3/7[bot_thickness,flare],angle(-7u,-h));
  170.  lft x9r=hround(tiny.lft x3l-.75u); bot y9r=vround .15h-o;
  171.  x9l:=good.x x9l; y9l:=good.y y9l;
  172.  filldraw stroke term.e(8,9,left,1,4); fi  % terminal
  173. if hefty: pickup crisp.nib; pos1(slab,90); pos2(hair,0);
  174.  top y1r=h; x1=x4; rt x2r=hround(w-1.5u); y2=y1l-eps;
  175.  arm(1,2,a,0,0);  % arm
  176. else: numeric flag_breadth; flag_breadth=7/8[vair,cap_curve];
  177.  pos1(flag_breadth,90); pos2(flag_breadth,60);
  178.  pos0(vair,90); top y1r=tiny.top y3; top y2r=vround .95h+o; y0r=y1r;
  179.  lft x1=tiny.lft x3l; x2r=.5[x1,x0]; rt x0=hround(w-1.6u);
  180.  erase fill top z1r--z1r...{right}z2r
  181.   --(x2r,top y1r)--cycle; % erase excess at top
  182.  filldraw stroke z1e...{right}z2e...z0e; fi  % flag
  183. penlabels(0,1,2,3,4,5,6,7,8,9,10); endchar;
  184.  
  185. dcchar "The numeral 6";
  186. beginchar("6",9u#,fig_height#,0);
  187. italcorr fig_height#*slant-.5u#;
  188. adjust_fit(0,0);
  189. numeric top_thickness,bot_thickness,side_thickness,pull;
  190. top_thickness=max(fine.breadth,vround(slab-2vair_corr));
  191. bot_thickness=max(fine.breadth,vround(slab-vair_corr));
  192. side_thickness=max(fine.breadth,hround 1/3[curve,cap_curve]);
  193. pull=min(.25,1.5superpull);
  194. pickup fine.nib; pos2(top_thickness,-270);
  195. pos3(side_thickness,-180); pos4(bot_thickness,-90);
  196. pos5(side_thickness,0); pos6(vair,90);
  197. lft x3r=w-rt x5r=hround max(.75u,1.5u-.5side_thickness);
  198. x4=x6-.1u=x2-u=.5w;
  199. top y2r=h+o; y3=.5[y2,y4]; bot y4r=-o;
  200. y5=.5[y4,y6]; top y6=vround 5/8h+o;
  201. path p; p=pulled_super_arc.l(3,4)(pull);
  202. numeric t; t=xpart(p intersectiontimes((x3r,y5)--(x4,y5)));
  203. pos7(thin_join,180); z7l=point t of p;
  204. (x,y6r)=whatever[z7l,z6l]; x6r:=min(x,.5[x5r,x6]);
  205. filldraw stroke pulled_super_arc.e(2,3)(pull)
  206.  & {{interim superness:=more_super; pulled_super_arc.e(3,4)(pull)}}
  207.  & {{less_tense; pulled_super_arc.e(4,5)(pull) & pulled_super_arc.e(5,6)(pull)}}
  208.  & z6e{left}...{direction t of p}z7e;  % arc and bowl
  209. if serifs: pos1(hair,-360); pos0(flare,-360);
  210.  rt x0r=max(rt x2+eps,hround(w-1.2u));
  211.  y0=vround min(.9h-.5flare,.85h+.5flare)+o;
  212.  {{less_tense; bulb(2,1,0)}};  % arc and bulb
  213. else: pos1(vround .1[top_thickness,flare],90);
  214.  top y1r=vround .97h+o; rt x1=hround(x5-.5);
  215.  filldraw stroke term.e(2,1,right,.9,4); fi  % terminal
  216. penlabels(0,1,2,3,4,5,6,7); endchar;
  217.  
  218. dcchar "The numeral 7";
  219. beginchar("7",9u#,fig_height#,0);
  220. italcorr fig_height#*slant-.5u#;
  221. adjust_fit(0,0);
  222. numeric arm_thickness, bot_width, top_shift, top_hair;
  223. if hefty: arm_thickness=Vround(slab+2stem_corr); top_shift=0;
  224.  bot_width=hround .51[curve,cap_curve]; top_hair=.4[thin_join,bot_width];
  225. else: arm_thickness=Vround .4[stem,cap_stem]; top_shift=.5u;
  226.  bot_width=flare; top_hair=cap_hair; fi
  227. if top_hair<tiny.breadth: top_hair:=tiny.breadth; fi
  228. pickup crisp.nib; pos2(arm_thickness,90); pos1(hair,180);
  229. top y2r=h; rt x2=hround(w-.75u+top_shift);
  230. lft x1r=hround(.75u+.5top_shift); y1=good.y(y2l-beak/2)-eps;
  231. arm(2,1,a,.3beak_darkness,-beak_jut);  % arm and beak
  232. pos3(hair,180); y3=good.y(y2r+beak/6)+eps; z3r=whatever[z1r,z.a0];
  233. penpos2'(eps,-90); z2'=z2r;
  234. arm(2',3,b,beak_darkness,x3r-x.a0);  % upward extension of beak
  235. pickup tiny.nib; pos4(top_hair,0); pos6(bot_width,0);
  236. bot y4=max(h-arm_thickness,h-slab,bot y2l); rt x4r=crisp.rt x2;
  237. lft x6l=hround(3.5u+top_shift-.5bot_width);
  238. if serifs: y6-.5bot_width=-o; filldraw z6l{down}..{up}z6r--cycle;  % bulb
  239. else: bot y6=-oo; fi
  240. if hefty: erase fill rt z4r--z4r...{down}z6r
  241.   --(rt x4r,y6)--cycle;  % erase excess at top
  242.  filldraw stroke z4e...{down}z6e;  % stroke
  243. else: pos5(top_hair,0); y5=2/3h; z5=whatever[z4,(.75u,y6)];
  244.  erase fill rt z4r--z4r--z5r--(rt x4r,y5)--cycle;  % erase excess at top
  245.  filldraw stroke z4e---z5e...{down}z6e; fi  % stroke
  246. penlabels(1,2,3,4,5,6); endchar;
  247.  
  248. dcchar "The numeral 8";
  249. beginchar("8",9u#,fig_height#,0);
  250. italcorr fig_height#*slant-.5u#;
  251. adjust_fit(0,0);
  252. numeric top_thickness,mid_thickness,bot_thickness,upper_side,lower_side,theta;
  253. top_thickness=max(fine.breadth,vround(slab-2vair_corr));
  254. bot_thickness=max(fine.breadth,vround(slab-vair_corr));
  255. x0=.5w; y0=.54h;
  256. if hefty: mid_thickness=vround 2/3vair; upper_side=hround(stem-3stem_corr);
  257.  lower_side=hround min(.5[curve,cap_curve]-stem_corr,upper_side+.25u);
  258.  penpos1(top_thickness,90); penpos2(upper_side,180);
  259.  penpos3(mid_thickness,270); penpos8(upper_side,360);
  260.  penpos4(mid_thickness,90); penpos7(lower_side,180);
  261.  penpos6(bot_thickness,270); penpos5(lower_side,360);
  262.  penpos0(vair,90); z3l=z0r; z4l=z0l;
  263.  x1=x6=.5w; x2r=w-x8r=hround u; x7r=w-x5r=hround .75u;
  264.  top y1r=h+o; bot y6r=-o; y2=y8=.5[y1l,y3l]; y7=y5=.5[y4l,y6l];
  265.  filldraw stroke pulled_arc.e(1,2)
  266.   & pulled_arc.e(2,3);  % left half of upper bowl
  267.  filldraw stroke pulled_arc.e(4,5)
  268.   & pulled_arc.e(5,6);  % right half of lower bowl
  269.  filldraw stroke pulled_arc.e(6,7)
  270.   & pulled_arc.e(7,4);  % left half of lower bowl
  271.  filldraw stroke pulled_arc.e(3,8)
  272.   & pulled_arc.e(8,1);  % right half of upper bowl
  273. else: pickup fine.nib; theta=90-angle(18u,h); slope:=-h/18u;
  274.  upper_side=max(fine.breadth,hround(.5[hair,stem]-stem_corr));
  275.  lower_side=hround(.5[hair,stem]+stem_corr);
  276.  pos1(top_thickness,-90); pos6(bot_thickness,-90);
  277.  x1=x6=.5w; top y1l=h+o; bot y6r=-o; pos0(cap_stem,theta);
  278.  lft x2l=w-rt x8l=hround 1.25u; lft x7r=w-rt x5r=hround .75u;
  279.  x2r-x2l=upper_side-fine; x5r-x5l=lower_side-fine;
  280.  ellipse_set(1l,2l,3l,0l); ellipse_set(1r,2r,3r,0r);
  281.  ellipse_set(6l,5l,4l,0l); ellipse_set(6r,5r,4r,0r);
  282.  numeric tau; tau=max(.8,.20710678/(superness-.5));
  283.  filldraw stroke z1e{left}..tension atleast tau..z2e{down}
  284.   ..z3e---z4e..z5e{down}..tension atleast tau..z6e{left};  % S stroke
  285.  pos7(lower_side,180); pos8(upper_side,180);
  286.  y7=.5[y5l,y5r]; y8=.5[y2l,y2r]; pos9(vair,90); z9=z0;
  287.  filldraw stroke z1e{right}..tension atleast tau..z8e{down}
  288.   ..tension atleast tau and atleast 1..{-18u,-.618h}z9e; % upper right stroke
  289.  filldraw stroke z6e{left}..tension atleast tau..z7e{up}
  290.   ..tension atleast tau and atleast 1..{18u,.5h}z9e; fi % lower left stroke
  291. penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
  292.  
  293. dcchar "The numeral 9";
  294. beginchar("9",9u#,fig_height#,0);
  295. italcorr fig_height#*slant-.5u#;
  296. adjust_fit(0,0);
  297. numeric top_thickness,bot_thickness,side_thickness,pull;
  298. top_thickness=max(fine.breadth,vround(slab-2vair_corr));
  299. bot_thickness=max(fine.breadth,vround(slab-vair_corr));
  300. side_thickness=max(fine.breadth,hround 1/3[curve,cap_curve]);
  301. pull=min(.25,1.5superpull);
  302. pickup fine.nib; pos2(bot_thickness,-90);
  303. pos3(side_thickness,0); pos4(top_thickness,90);
  304. pos5(side_thickness,180); pos6(vair,270);
  305. w-rt x3r=lft x5r=hround max(.75u,1.5u-.5side_thickness);
  306. x4-.1u=x6+.1u=x2+.75u=.5w;
  307. bot y2r=-o; y3=.5[y2,y4]; top y4r=h+o;
  308. y5=.5[y4,y6]; bot y6=vround 3/8h-o;
  309. path p; p=pulled_super_arc.l(3,4)(pull);
  310. numeric t; t=xpart(p intersectiontimes((x3r,y5)--(x4,y5)));
  311. pos7(thin_join,360); z7l=point t of p;
  312. (x,y6r)=whatever[z7l,z6l]; x6r:=max(x,.5[x5r,x6]);
  313. filldraw stroke pulled_super_arc.e(2,3)(pull)
  314.  & {{interim superness:=more_super; pulled_super_arc.e(3,4)(pull)}}
  315.  & {{less_tense; pulled_super_arc.e(4,5)(pull) & pulled_super_arc.e(5,6)(pull)}}
  316.  & z6e{right}...{direction t of p}z7e;  % arc and bowl
  317. if serifs: pos1(hair,-180); pos0(flare,-180);
  318.  lft x0r=min(lft x2-eps,hround 1.2u);
  319.  y0=vround max(.1h+.5flare,.15h-.5flare)-o;
  320.  {{less_tense; bulb(2,1,0)}};  % arc and bulb
  321. else: pos1(.1[bot_thickness,flare],-120);
  322.  bot y1r=vround .07h-o; lft x1r=hround 1.3u;
  323.  filldraw stroke term.e(2,1,left,.9,4); fi  % terminal
  324. penlabels(0,1,2,3,4,5,6,7); endchar;
  325.  
  326. endinput;
  327.